/* Just an an extra, this program also leaves some keywords unchanged, 
 * and handles commments and constants
 */

options {
  LOOKAHEAD=1;
}


PARSER_BEGIN(Q1)

public class Q1 {

  /*** List of some common Prolog built-in predicates ***/
  static String built_ins =  "assert assertz bagof fail is module nl read repeat retract retractall see seen setof tell told true write";

  /*** Main routine - just call parser ***/
  public static void main(String args[]) throws ParseException {
    Q1 parser = new Q1(System.in);
    try {
      parser.prolog();
    } catch (ParseException x) {
      System.out.println("Exiting due to parse error.");
      throw x;
    }
  }

}

PARSER_END(Q1)


SKIP : /*** Ignoring spaces/tabs/newlines ***/
{
    " "
  | "\t"
  | "\n"
  | "\r"
}

SPECIAL_TOKEN : /* COMMENTS */
{
  <OneLineComment : "%" (~["\n","\r"])* ("\n"|"\r"|"\r\n") >
| <ManyLineComment : "/*" (~["*"])* "*" ("*" | (~["*","/"] (~["*"])* "*"))* "/" >
}
 
TOKEN :  /* Predicates and variables */
{
  < PRED :  ["a" - "z"](<LETDIG>)* >
| < VAR : (["A" - "Z"](<LETDIG>)*) | (["_"](<LETDIG>)+)  >
| < #LETDIG : ["a" - "z", "A" - "Z", "_", "0"-"9"] >
| < FSTOP : "." >
}

TOKEN : /* Some extra ones, just for fun */
{
  < STRING_CONST : "\""(~["\""])+"\"" >
| < CHAR_CONST : "\'"(~["\'"])+"\'" >
| < NUM_CONST : (["0"-"9"])+ >
}

TOKEN : /* Anything not recognised so far */
{
  < OTHER : ~[] >
}

/*************************/
/***** GRAMMAR RULES *****/
/*************************/


void prolog() :
{}
{
  ( tok()  )+ <EOF>
}

void tok() :
{}
{
  <PRED>	 
  { 
    if (built_ins.indexOf(token.image) != -1) // Is a built_in predicate
      System.out.print(token.image); 
    else
      System.out.print("p");
  }
| <VAR>		 { System.out.print("V"); }
| <FSTOP>	 { System.out.println("."); }
| <STRING_CONST> { System.out.print("S"); }
| <CHAR_CONST>   { System.out.print("C"); }
| <NUM_CONST>	 { System.out.print("N"); }
| <OTHER>	 { System.out.print(token.image); }
}